10 REM Adressensuche Rev. E4, 5.10.2015
20 LA$=CHR$(10)					:REM Abschlusssequenz Ausgabe
30 LI$=LA$					:REM Abschlusssequenz Eingabe
40 ST%=0					:REM Anfang Adressbereich
50 EN%=30					:REM Ende Adressbereich
60 IEC INIT
70 IEC TIMEOUT 1
80 Z%=0						:REM Zähler für Funde
90 ESC$=CHR$(27)

100 REM Abschlusssequenz schreiben
110 FOR I%=ST% TO EN%
120 IEC LASTOUT I%,LA$
130 IEC LASTIN I%,LI$
140 NEXT I%

200 REM Maske anlegen
210 PRINT CHR$(12)
220 PRINT ESC$+"Y"+CHR$(53)+CHR$(32);
230 PRINT ESC$+"A2";
240 PRINT ESC$+"Y"+CHR$(53)+CHR$(32)+"__________________________________";
250 PRINT ESC$+"Y"+CHR$(54)+CHR$(32)+"Busadresse  Fehler        Zeile";
260 PRINT CHR$(1)+"Adressensuche Rev. E4, 5.10.2015"
270 PRINT
280 PRINT"Adresse","Status","ID?","*IDN?"

300 REM Schleife
310 ON ERROR GOTO 1000
320 FOR J%=ST% TO EN%

400 REM Adresse
410 J$=STR$(J%)	
420 J$=RIGHT$(J$,LEN(J$)-1)			:REM führendes Leerzeichen entfernen
430 IEC PRINT #J%," "

500 REM POLL
510 A%=-1
520 IEC POLL #J%,A%
530 P$=STR$(A%)				
540 P$=RIGHT$(P$,LEN(P$)-1)			:REM führendes Leerzeichen entfernen

600 REM ID?
610 A$=""
620 IEC PRINT #J%,"ID?"
630 FOR K%=1 TO 1000
640 NEXT K%
650 IEC INPUT #J%,A$
660 IF A$="" THEN A$="---"

700 REM *IDN?
710 B$=""
720 IEC PRINT #J%,"*IDN?"
730 FOR K%=1 TO 1000
740 NEXT K%
750 IEC INPUT #J%,B$
760 IF B$="" THEN B$="---"

800 REM Ausgabe
820 PRINT ESC$+"Y"+CHR$(35+Z%)+CHR$(32)+J$;
830 PRINT ESC$+"Y"+CHR$(35+Z%)+CHR$(46)+P$;
840 PRINT ESC$+"Y"+CHR$(35+Z%)+CHR$(60)+A$;
850 PRINT ESC$+"Y"+CHR$(35+Z%)+CHR$(74)+B$
860 PRINT ESC$+"Y"+CHR$(56)+CHR$(32);		
870 PRINT ESC$+"k"				:REM letzte Fehlermeldung löschen
880 Z%=Z%+1
890 NEXT J%

900 REM Programmende
910 IEC LOCAL
920 PRINT ESC$+"Y"+CHR$(50)+CHR$(32)+"fertig"
930 END

1000 REM Fehlerbehandlung
1010 PRINT ESC$+"Y"+CHR$(56)+CHR$(32)+J$,ERR,ERL
1020 IF ERL>430 GOTO 1100
1030 J%=J%+1					:REM nächste Adresse
1040 IF J% > EN% GOTO 900
1050 RESUME 400					

1100 IF ERL>520 GOTO 1200
1110 P$="---"
1120 RESUME 600

1200 IF ERL>620 GOTO 1300
1210 RESUME 700

1300 IF ERL>650 GOTO 1400
1310 IEC CLEAR #J%
1320 A$="---"
1330 RESUME 700

1400 IF ERL>720 GOTO 1500
1410 B$="---"
1420 RESUME 800

1500 IEC CLEAR #J%
1510 B$="*---"
1520 RESUME 800

2000 END