10 REM Adressensuche Rev. E4.2, 13.10.2015
20 IEC INIT
30 IEC TIMEOUT 1
40 LA$=CHR$(10)
50 LI$=LA$
60 ESC$=CHR$(27)
70 ST%=0
80 EN%=30
90 Z%=0
100 REM Abschlusssequenz schreiben
110 FOR I%=ST% TO EN%
120 IEC LASTOUT I%,LA$
130 IEC LASTIN I%,LI$
140 NEXT I%
200 REM Maske anlegen
210 PRINT CHR$(12)
220 PRINT ESC$+"Y"+CHR$(53)+CHR$(32);
230 PRINT ESC$+"A2";
240 PRINT ESC$+"Y"+CHR$(53)+CHR$(32)+"__________________________________________________";
250 PRINT ESC$+"Y"+CHR$(54)+CHR$(32)+"Busadresse  Fehler        Zeile         Stat";
260 PRINT CHR$(1)+"Adressensuche Rev. E4.2, 13.10.2015"
270 PRINT ESC$+"Y"+CHR$(34)+CHR$(32)+"Adr.";
275 PRINT ESC$+"Y"+CHR$(34)+CHR$(40)+"Poll";
280 PRINT ESC$+"Y"+CHR$(34)+CHR$(48)+"ID?";
285 PRINT ESC$+"Y"+CHR$(34)+CHR$(68)+"*IDN?"
300 REM Schleife
310 ON ERROR GOTO 1000
320 FOR J%=ST% TO EN%
400 REM Adresse
410 J$=STR$(J%)
420 IF LEFT$(J$,1)=" " THEN J$=RIGHT$(J$,LEN(J$)-1)
430 IEC PRINT #J%," "
500 REM Poll
510 A%=-1
520 IEC POLL #J%,A%
530 IF A%>0 THEN P$=STR$(A%) ELSE P$="---"
540 IF LEFT$(P$,1)=" " THEN P$=RIGHT$(P$,LEN(P$)-1)
600 REM ID?
610 A$=""
620 IEC PRINT #J%,"ID?"
630 FOR K%=1 TO 1000
640 NEXT K%
650 IEC INPUT #J%,A$
660 IF A$="" THEN A$="---"
700 REM *IDN?
710 B$=""
720 IEC PRINT #J%,"*IDN?"
730 FOR K%=1 TO 1000
740 NEXT K%
750 IEC INPUT #J%,B$
760 IF B$="" THEN B$="---"
800 REM Ausgabe
810 PRINT ESC$+"Y"+CHR$(35+Z%)+CHR$(32)+J$;
820 PRINT ESC$+"Y"+CHR$(35+Z%)+CHR$(40)+P$;
830 PRINT ESC$+"Y"+CHR$(35+Z%)+CHR$(48)+A$;
840 PRINT ESC$+"Y"+CHR$(35+Z%)+CHR$(68)+B$
850 PRINT ESC$+"Y"+CHR$(56)+CHR$(32);
860 PRINT ESC$+"k"
870 Z%=Z%+1
880 NEXT J%
900 REM Programmende
910 IEC LOCAL
920 PRINT ESC$+"Y"+CHR$(50)+CHR$(32)+"fertig"
930 END
1000 REM Fehlerbehandlung
1010 IEC STATUS S%
1020 PRINT ESC$+"Y"+CHR$(56)+CHR$(32)+J$,ERR,ERL,S%
1030 IF ERL>430 GOTO 1100
1040 J%=J%+1
1050 IF J%>EN% GOTO 900
1060 RESUME 400
1100 REM #520
1110 IF ERL>520 GOTO 1200
1120 P$="---"
1130 RESUME 600
1200 REM #620
1210 IF ERL>620 GOTO 1300
1220 RESUME 700
1300 REM #650
1310 IF ERL>650 GOTO 1400
1320 IEC CLEAR #J%
1330 A$="---"
1340 RESUME 700
1400 REM #720
1410 IF ERL>720 GOTO 1500
1410 RESUME 760
1500 REM #750
1510 IEC CLEAR #J%
1520 IEC POLL #J%,A
1530 IEC CLEAR #J%
1540 RESUME 760
2000 END